: O. Yuanying

iPhone用に動画を公開す

といっても、自分用ですけどね。

Woopieを観てたら、 3G経由でも結構きれいな画質で動画が観れることがわかったので、 外出先でiPhoneに入れてない動画なぞを観たいときに、 ネット経由で観れるといいなーと思いまして。

Mac用にOrbがあれば一番良いんだけど、 残念ながら無いので自宅のapacheからファイルを落とせるようにします。

ファイルの公開

アップしたファイルをiPhoneできれいに一覧するphpスクリプト。

iPhone用に動画をエンコード

QuickTime Pro の Export メニューからファイルを一つずつ選んで、 iPhone 用にエンコードしても良いんだけど、 面倒なので AppleScript を書いて一度にエンコード。

初めて書いた AppleScript。


on run
    activate
    set itemList to choose file with prompt "ムービーを選択してください" default location (path to home folder) with multiple selections allowed without invisibles
    my saveAsQuickTimeMovie(itemList)
end run

on open inputList
    my saveAsQuickTimeMovie(inputList)
end open

on saveAsQuickTimeMovie(movieList)
    activate
    set saveFolder to choose folder with prompt "保存先フォルダを指定してください" default location (path to movies folder)

    tell application "QuickTime Player"
        launch
        activate
        stop every document
        close every document saving no
        repeat with aMovie in movieList
            open aMovie
            set file_name to name of document 1
            set new_file to ((saveFolder as text) & file_name) as string
            -- 拡張子を外す
            set new_file to my deleteNameExtention(new_file)
            -- 拡張子を付ける
            set new_file to (new_file) & ".m4v"
            
            with timeout of (1 * 60 * 60) seconds
                export document 1 to new_file as iPhone
            end timeout
            
            close document 1 saving no
        end repeat
        quit
    end tell
end saveAsQuickTimeMovie

on deleteNameExtention(inName)
    if inName contains "." then
        repeat with i from (count inName) to 1 by -1
            if text i of inName is "." then
                set i to i - 1
                if i < 1 then
                    return inName
                end if
                return text 1 thru i of inName
            end if
        end repeat
    end if
    return inName
end deleteNameExtention

といってもここらへんをほとんどコピッタだけ。

  1. ムービーをQuickTime形式へ変換するAppleScript: 影羽連盟
  2. applescriptのtimed outの回避方法は
  3. 主にAppleScriptの小物発表: Mac用ニコニコ動画ダウンロードソフト : miqDownloader 0.3.0

ほとんど1.なんだけど、エンコード中にタイムアウトが発生したので2.を参考にタイムアウトを1時間に。 あと、拡張子の変更が少しうまくいかなかったので3.のスクリプトからその処理をぱくる。

できあがり

iphone.jpg

こんな感じで観たい動画がリストアップ。画質も結構きれい。

なかなか満足である。